mkpp.csh

Go to the documentation of this file.

#!/bin/tcsh -f
 
onintr irq_ctrlc
 
unsetenv CWB_MERGE_LABEL
unsetenv CWB_PP_OPTIONS
 
if ((( $1 == '' ))) then
  setenv CWB_MERGE_LABEL "M1"   # default
else
  setenv CWB_MERGE_LABEL $1
endif
 
if ((( $4 != 'merge' ) && ( $4 != 'veto' ) && ( $4 != 'cut' ) && ( $4 != 'report' ) && ( $4 != 'all' ) &&( $4 != '' ))) then
  echo ""
  echo \'$4\' "is a wrong cwb pp option"
  echo ""
  echo "available options"
  echo "          no options -> all (default)"
  echo "          merge : execute merge"
  echo "          veto  : execute veto"
  echo "          cut   : execute cut"
  echo "          report: execute report"
  echo "          all   : execute merge+veto+cut+report"
  echo ""
  exit 1
else
  if ((( $4 == '' ))) then
    setenv CWB_PP_OPTIONS  "all"
  else
    setenv CWB_PP_OPTIONS  $4
  endif
endif
 
if ((( $CWB_PP_OPTIONS == "merge" ) || ( $CWB_PP_OPTIONS == "all" ))) then
  ${CWB_SCRIPTS}/cwb_merge.csh   $CWB_MERGE_LABEL '--nthreads 10'
  if ( $? != 0) exit 1
endif
 
if ((( $CWB_PP_OPTIONS == "veto" ) || ( $CWB_PP_OPTIONS == "all" ))) then
  ${CWB_SCRIPTS}/cwb_setveto.csh $CWB_MERGE_LABEL
  if ( $? != 0) exit 1
endif
 
if ((( $CWB_PP_OPTIONS == "cut" ) || ( $CWB_PP_OPTIONS == "all" ))) then
  ${CWB_SCRIPTS}/cwb_setcuts.csh $CWB_MERGE_LABEL.V_hvetoH_userHV "--tcuts bin1_cut --label bin1_cut"
  if ( $? != 0) exit 1
 
  # bin0_cut is used to select the exclusive HV time
  ${CWB_SCRIPTS}/cwb_setcuts.csh $CWB_MERGE_LABEL.V_hvetoH_userHV "--tcuts bin0_cut --label bin0_cut"
  if ( $? != 0) exit 1
 
  # create exclusive livetime tree for bin0_cut -> only the zero lag leaf 'live' is updated -> overwrite the livetree file created in the previous step
  root -n -l -b ${CWB_PPARMS_FILES} ${CWB_CONFIG}/MACROS/CreateExclusiveLiveTimeFile.C\‍(\"$CWB_MERGE_LABEL.V_hvetoH_userHV\",\"BURST_IMBH\",\"K99_ejobs_H1_V1_cat012_not_H1_L1.txt\",\"O3a\",\"C_bin0_cut\"\‍)
  if ( $? != 0) exit 1
endif
 
if ((( $CWB_PP_OPTIONS == "report" ) || ( $CWB_PP_OPTIONS == "all" ))) then
  # create report bin1_cut
  ${CWB_SCRIPTS}/cwb_report.csh  $CWB_MERGE_LABEL.V_hvetoH_userHV.C_bin1_cut create
  if ( $? != 0) exit 1
 
  # set ifar to bin1_cut
  ${CWB_SCRIPTS}/cwb_setifar.csh $CWB_MERGE_LABEL.V_hvetoH_userHV.C_bin1_cut '--xtsel run>=0  --label ifar --xfile report/postprod/'$CWB_MERGE_LABEL'.V_hvetoH_userHV.C_bin1_cut.R_rMRA_hveto_i0cc00_i1rho0_freq16_512/data/far_rho.txt --mode exclusive'
  if ( $? != 0) exit 1
 
  # create report bin0_cut
#  ${CWB_SCRIPTS}/cwb_report.csh  $CWB_MERGE_LABEL.V_hvetoH_userHV.C_bin0_cut create
#  if ( $? != 0) exit 1
 
  # the bin0_cut background is a symbolic link to bin1_cut 
  ln -sf $CWB_MERGE_LABEL.V_hvetoH_userHV.C_bin1_cut.R_rMRA_hveto_i0cc00_i1rho0_freq16_512 report/postprod/$CWB_MERGE_LABEL.V_hvetoH_userHV.C_bin0_cut.R_rMRA_hveto_i0cc00_i1rho0_freq16_512 
  if ( $? != 0) exit 1
 
  # set ifar to bin0_cut using the the bin1_cut background
  ${CWB_SCRIPTS}/cwb_setifar.csh $CWB_MERGE_LABEL.V_hvetoH_userHV.C_bin0_cut '--xtsel run>=0  --label ifar --xfile report/postprod/'$CWB_MERGE_LABEL'.V_hvetoH_userHV.C_bin1_cut.R_rMRA_hveto_i0cc00_i1rho0_freq16_512/data/far_rho.txt --mode exclusive'
  if ( $? != 0) exit 1
endif
 
unsetenv CWB_MERGE_LABEL
unsetenv CWB_PP_OPTIONS
 
exit 0
irq_ctrlc:
  ps T | grep root | awk '{print $1}' | xargs kill -9
  exit 1